크롬 다중 세션 생성기(스크립트 포함)

기타

크롬 다중 세션 생성기(스크립트 포함)

indeep 2025. 1. 25. 22:57

회사 업무를 수행하다 보면 현재 개발 중인 서비스에 로그인해서 테스트를 진행하는 경우가 빈번하게 발생한다.

~~단위 테스트~~, ~~통합 테스트~~를 이용해서 로직의 안정성을 높이는 것도 엄청 중요한 테스트지만 내가 직접 하나하나 버튼을 클릭하면서 눈으로 확인하는 테스트도 중요한 테스트라고 생각한다.

(물론 SI 특성상 테스트 코드를 짜는 것 자체가 불가능하다고 생각한다. 거의 주 단위로 바뀌는 요구사항 덕분에...)

그렇게 크롬으로 로그인 계정 하나 만들어서 서비스 접속하고 이것 저것 눌러보고...

다른 계정으로도 동시에 접속하기 위해 시크릿 모드를 열어서 이것 저것 눌러보고....

또 다른 세션을 이용해야 하는데 크롬은 기본 세션, 시크릿 모드 2개가 끝이라 엣지를 켜서 이것저것 눌러보고...

만약에 10개의 서로 다른 레벨 or 등급을 가진 사람끼리 직접 로그인해서 테스트를 진행해야 한다면??

가장 간단하게는 옆 동료한테 부탁을 해보는 것도 방법이다.

만약에 거절당했다면?

어쩔 수 있나...내가 직접 방법을 찾는 수밖에

어떻게?

라는 여러분과 나를 위해 크롬에서 다중 세션을 편리하게 이용할 수 있는 bat 프로그램을 하나 만들기로 결정했다.

@echo off
chcp 65001 > nul

setlocal enabledelayedexpansion

:: 세션 이름 입력 요청
:session_loop
echo 실행할 세션 이름을 입력해주세요. (종료하려면 'exit', 캐시 삭제는 'reset' 입력)
set /p "session_name=세션 이름: "

if /i "%session_name%" == "exit" (
    echo 프로그램을 종료합니다.
    exit /b
)

:: reset일 때는 레이블로 이동
if /i "%session_name%" == "reset" (
    goto reset_confirmation
)

:: 크롬 실행
start chrome.exe --user-data-dir="C:\\work\\ChromeUsers\\%session_name%"
echo 크롬이 "%session_name%" 세션으로 실행되었습니다.
echo.

goto session_loop

::-----------------------------------
:reset_confirmation
echo 모든 세션 캐시를 삭제하시겠습니까? (Y / N)
set /p "cache_status=입력: "

if /i "%cache_status%" == "Y" (
    if exist "C:\\work\\ChromeUsers\\" (
        rd /s /q "C:\\work\\ChromeUsers"
        echo C:\\work\\ChromeUsers의 모든 세션 캐시가 삭제되었습니다.
    ) else (
        echo C:\\work\\ChromeUsers 폴더가 존재하지 않습니다.
    )
    goto session_loop
) else if /i "%cache_status%" == "N" (
    goto session_loop
) else (
    echo Y 또는 N을 입력해주세요.
    goto reset_confirmation
)

전체 코드는 위와 같이 구성이 됩니다.(챗 GPT와 함께라면 뭐든 두렵지 않아)

위 코드는 간단하게 요약하면 크롬을 실행할 때 여러 개의 세션으로 구성할 수 있게 도와줍니다.

(세션 이름을 입력하면 C:\work\ChromeUsers 폴더에 해당 이름의 세션을 생성합니다.)